<sentencia> -> <sentencia expresión> |

<sentencia compuesta> |

<sentencia de selección> |

<sentencia de iteración> |

<sentencia etiquetada> |

<sentencia de salto>

<sentencia expresión> -> <expresión>? ;

<sentencia compuesta> -> {<lista de declaraciones>? <lista de sentencias>?}

<lista de declaraciones> -> <declaración> |

<lista de declaraciones> <declaración>

<lista de sentencias> -> <sentencia> | <lista de sentencias> <sentencia>

***La sentencia compuesta también se denomina bloque.***

<sentencia de selección> -> if (<expresión>) <sentencia> |

if (<expresión>) <sentencia> else <sentencia> |

switch ***(<expresión>)*** <sentencia>

***La expresión <expresión> controla un switch debe ser de tipo entero.***

<sentencia de iteración> -> while (<expresión>) <sentencia> |

do <sentencia> while (<expresión>) ; |

for (<expresión>? ; <expresión>? ; <expresión>?) <sentencia>

<sentencia etiquetada> -> case <expresión constante> : <sentencia> |

default : <sentencia> |

<identificador> : <sentencia>

***Las sentencias case y default se utilizan solo dentro de una sentencia switch.***

<sentencia de salto> -> continue ; |

break ; |

return <expresión>? ; |

goto <identificador> ;

***La sentencia continue solo debe aparecer dentro del cuerpo de un ciclo. La sentencia break solo debe aparecer dentro de un switch o en el cuerpo de un ciclo. La sentencia return con una expresión no puede aparecer en una función void.***